Atari Mega Archive 2/Atari Mega Archive CD - Volume 2.iso/8bit/cislib_b/pl1020.lgo

Text File | 1995-04-22 | 2KB | 151 lines

TO DOC
TS CT
PR [THE following procedures will link]
PR [your LOGO turtles and the Atari 1020]
PR [Printer - Plotter.]
PR []
PR [While executing a LOGO graphics]
PR [procedure with the command]
PR []
PR []
PR [DRAW [procedure]]
PR []
PR []
PR [your 1020 will plot whatever is]
PR [drawn on the screen.]
PR []
PR [Press RETURN for MORE]
MAKE "A RC
CT
PR [For a little fun, press BREAK and]
PR [type the following commands right]
PR [now!]
PR []
PR []
PR [DRAW [SQUIRAL 117\]]]
PR []
PR [DRAW [FRACTAL SN 300 9\]]]
PR []
PR []
PR [Press BREAK to try demonstration]
PR [or]
PR [Press RETURN for more documentation]
MAKE "A RC
CT
PR [Procedures intended to be drawn on]
PR [your Atari 1020 Printer - Plotter]
PR [must be modified to substitute the]
PR [F and B procedures for the usual FD]
PR [and BK primitives.]
PR []
PR [Two procedures ( P.PROC & P.PROCS]
PR [are included to print out your]
PR [procedures on the plotter.]
PR [] PR []
PR [Press RETURN for MORE.]
MAKE "A RC
CT
PR [These procedures are by DAVID]
PR [THORNBURG and were published in the]
PR [March, 1984, issue of COMPUTE!]
PR []
PR [If you'd like to find some graphics]
PR [fuel for your plotter, check out]
PR [THORNBURG's]
PR []
PR [Computer Art and Animation: A User's]
PR [Guide to Atari Logo]
PR [] PR [Available from:]
PR [MICRO BOOKS - - Addison - Wesley]
PR [] PR []
PR [Have FUN!]
END

TO P.PROC :PROCEDURE_NAME
SETWRITE "P:
( TYPE CHAR 27 CHAR 27 CHAR 14 )
PO :PROCEDURE_NAME
SETWRITE []
END

TO P.PROCS
SETWRITE "P:
( TYPE CHAR 27 CHAR 27 CHAR 14 )
POPS
SETWRITE []
END

TO SQUIRAL :ANGLE
MAKE "SIDE 0
REPEAT 180 [F :SIDE RT :ANGLE MAKE "SIDE :SIDE + 1]
END

TO PENRED
( TYPE CHAR 67 CHAR 51 )
END

TO PENGREEN
( TYPE CHAR 67 CHAR 50 )
END

TO PENBLUE
( TYPE CHAR 67 CHAR 49 )
END

TO PENBLACK
( TYPE CHAR 67 CHAR 48 )
END

TO C
CS
PR "M0,0
END

TO B :X
BK :X
PLOT
END

TO DRAW :LIST
SETWRITE "P:
( TYPE CHAR 27 CHAR 27 CHAR 7 )
( PR "M240,0\*I\*M INT 2 * YCOR ", INT ( - 2 ) * XCOR )
RUN :LIST
SETWRITE []
END

TO PLOT
( PR IF PEN = "PD ["D] ["M] INT 2 * YCOR ", INT ( - 2 ) * XCOR )
END

TO FRACTAL
PU SETPOS [-150 0] PLOT SETH 90 PD
HT
END

TO F :X
FD :X
PLOT
END

TO SN :S :L
IF :S < :L [F :S STOP]
SN :S / 3 :L
LT 60
SN :S / 3 :L
RT 120
SN :S / 3 :L
RT 120
SN :S / 3 :L
LT 120
SN :S / 3 :L
LT 120
SN :S / 3 :L
RT 60
SN :S / 3 :L
END


MAKE "A "\